package Mac::Text::MPEdit;

=head1 NAME

B<MPE.pm> - A Text Editor for use with MacPerl

=head1 DESCRIPTION

B<MPEdit.pm> opens a MacPerl window in which text can be edited in the usual manner. The contents of the window may be taken from an existing file, or some other text string generated in the program which uses the module, or a new document may be created. The edited text can be saved to the file it came from, or a new file, or merely returned to the calling program.

The B<MPEdit.pm> window creates new C<MPFile> and C<MPEdit> menus in the Menu Bar which provide means to control the editing process. Under the C<File> menus are options C<Open>, C<Close>, C<Save> and C<Save As> which have the usual meanings. There is no C<New> since the new window is created by the calling program. Similarly C<Quit> merely closes the window, since it is unlikely the user would ever want MacPerl itself to be shut down.

Options provided under the C<MPEdit> menu include C<Cut>, C<Copy> and C<Paste> which transfer text selections to and from the private scrap. C<Select All> does what is expected and in conjunction with the delete key can be used to clear the window. C<Find> and C<Find Again> search is supported, with C<Find> always starting from the beginning of the document.

The body of text in the window is scrolled automatically so that the caret and any text selected in a C<Find> operation is kept in the visible region. Fully functional scroll bars, with proper mouse tracking,  allow the text to be scrolled manually.

=head1 INSTALLATION

The file B<MPEdit.pm> should be placed in a folder B<Text> which should be placed in a folder B<Mac> in MacPerl's site-library path.

=head1 SYNOPSIS

	use Mac::Text::MPEdit;
	
	PREFS [ HASH REFERENCE (optional)]
	MPE   [ STRING or FILE REFERENCE ]
	MPE_QUIT
	$Version
	
	
=head1 METHODS

Essentially there are two main methods exported by B<MPE.pm>, one allows session preferences for the window to be set and the other to import text either from an existing file, or from a program variable.

The using program should have an C<END> block including the line C<MPE_QUIT> so that if the program terminates unexpectedly whilst the C<MPEdit> window is active, the window, control and other handles are disposed of in an orderly fashion. Failure to this may result in a frozen MPEdit window being left stranded on the screen or the machine may even crash.

=over 4

=item B<PREFERENCES>

The preferences are set by a call to C<PREFS> and remain in force for the session, that is to say the duration of the calling program, or until reset by a second call to C<PREFS>. There is no limit on the number of calls during the course of the program and no need for the preferences be set at all if the default values are acceptable. The preferences must be passed as a hash reference with the following syntax:

    $prefs = {
        {wh}   => 550,    # window horizontal size
        {wv}   => 300,    # window vertical size
        {lw}   => 500,    # line length
        {font} => 4,      # font ID
        {size} => 9,      # font size
        {x_tl} => 10,     # top left corner horizontal position
        {y_tl} => 52,     # top left corner vertical position
    }
    
    PREFS($prefs);
    
The preferences hash above shows the default values for all the parameters which may be altered. In practice the hash used may included any combination of the available keys with any (reasonable) values and listed in any order.

=item B<CONTENT>

The windows content is determined by the argument to C<MPE>. If this is a string variable, the string is written to the window, but if it is a scalar reference the object referred to is taken to be the full-path name of a file, and the module attempts to open the file and display the contents.

    MPE(\$var);    # displays contents of file named $var
    MPE($var);     # displays string value of $var
    MPE();         # opens an empty window
    
=item B<SHUT-DOWN>

To ensure that an orderly shut-down, the calling program should have an C<END{}> block containing the line:

    END { QUIT() }
    
=item B<EXAMPLE PROGRAM>

=back

    #!perl

    use Mac::Text::MPE;

    PREFS({
        x_tl => 50,
        y_tl => 122
    });

    $file_1 = $ENV{MACPERL}.'Perl Artistic License';  # display file
    $file_2 = $ENV{MACPERL}.'README';                 # another file
    $str_1 = 'hello there, here is a string';         # a string...  
           
    print STDERR MPE(\$file_1);   # prints the edited window...
    print STDERR MPE(\$file_2);   # ...contents to STDERR
    $x =  MPE($str_1);            # returns window contents to $x
    print STDERR "$x\n";

    END { QUIT() }
    
=head1 AUTHOR

Copyright (c) 1997 Alan J. Fry C<E<lt>ajf@afco.demon.co.ukE<gt>>

All rights reserved. 

This program is free software; you can redistribute it and/or modify it under
the same terms as Perl itself.

=head1 HISTORY

    Version 1.0.0 30 November 1998    Original version
    Version 1.1   01 December 1998    Module restructured
                                      Documentation revised 

=cut

BEGIN {
    use Exporter;
    use vars qw(@ISA @EXPORT);
    @ISA = qw(Exporter);
    @EXPORT = qw( $Version &MPE &PREFS &MPE_QUIT)
}
my ($mpe, $ret, $prefs);

sub MPE {
    my ($data) = @_;

    $mpe = MPEditWindow->new($prefs);
    if (ref $data eq 'SCALAR') {
        $mpe->open_file($$data);
    }
    else{
        $mpe->import_string($data)
    }
    $ret = $mpe->edit();
}

sub PREFS { 
    my ($data) = @_; 
    $prefs = $data
}

sub MPE_QUIT { $mpe->DESTROY if defined $mpe }

package MPEditWindow;

$Version = 'v1.1 1998/12/01 17:20:56';

use Mac::Windows;
use Mac::QuickDraw;
use Mac::Events;
use Mac::Events qw(@Event $CurrentEvent);
use Mac::TextEdit;
use Mac::Controls;
use Mac::Menus;

use strict;
$|=1;

sub new {
    my($pkg, $data) = @_;
    my $ref = {};
    $ref->{wh}   = defined $data->{wh}   ? $data->{wh}   : 550;
    $ref->{wv}   = defined $data->{wv}   ? $data->{wv}   : 300;
    $ref->{lw}   = defined $data->{lw}   ? $data->{lw}   : 500;
    $ref->{font} = defined $data->{font} ? $data->{font} : 4;
    $ref->{size} = defined $data->{size} ? $data->{size} : 9;
    $ref->{x_tl} = defined $data->{x_tl} ? $data->{x_tl} : 10;
    $ref->{y_tl} = defined $data->{y_tl} ? $data->{y_tl} :  52;
    $ref->{title} = 'Untitled';
    $ref->{saved} = 1;
    bless $ref, $pkg;

    my $win_r = Rect->new(0, 0, $ref->{wh}, $ref->{wv});
    my $bnd = OffsetRect($win_r, $ref->{x_tl}, $ref->{y_tl});
    my $win = MacWindow->new(NewCWindow($bnd, $ref->{title}, 1, 8, 1));

    my $chr = Rect->new(-1, $win_r->bottom-15, $win_r->right-14, $win_r->bottom+1);
    my $ch  = $win->new_control($chr, 0, 1, 0, 0, 1, scrollBarProc());
    HiliteControl($ch->{control}, -1);

    my $cvr = Rect->new($win_r->right-15, -1, $win_r->right+1, $win_r->bottom-14);
    my $cv  = $win->new_control($cvr, 0, 1, 0, 0, 1, scrollBarProc());
    HiliteControl($cv->{control}, -1);

    my $port = $win->window->portRect;
    my $view = Rect->new(0, 0, $port->right-16, $port->bottom-16);

    my $dest = Rect->new(5, 5, $ref->{lw}, $ref->{wv});
    SetPort $win->window;
    TextFont($ref->{font});
    TextSize($ref->{size});
    my $hte = TENew($dest, $view);
    TESetSelect(0, 0, $hte);

    $win->sethook('key',    sub { $ref->get_key(@_) });
    $win->sethook('redraw', sub { $ref->do_draw(@_) });
    $win->sethook('click',  sub { $ref->get_click(@_) });
    $win->sethook('layout', sub { $ref->revise_layout });
    $win->sethook('idle',   sub { TEIdle($hte) } );
    @Event[mouseDown] =     sub { $ref->mousePress(@_) };

    $cv->sethook('track', sub { $ref->vertical_scroll(@_) });
    $ch->sethook('track', sub { $ref->horizontal_scroll(@_) });

    $ref->{oldEdit} = GetMenuHandle(130);
    $ref->{oldFile} = GetMenuHandle(129);
    $ref->{2048} = '';
    $ref->{2049} = '';
    $ref->new_menu();
    $ref->{newEdit} = $ref->{2048}->{menu};
    $ref->{newFile} = $ref->{2049}->{menu};
    $ref->change_menu_bar();

    $ref->{OK}   = 0;
    $ref->{win}  = $win;
    $ref->{ptr}  = $win->window;
    $ref->{port} = $port;
    $ref->{cv}   = $cv->{control};
    $ref->{ch}   = $ch->{control};
    $ref->{view} = $view;
    $ref->{dest} = $dest;
    $ref->{hte}  = $hte;
    $ref->{file} = '';
    $ref->{doc}  = '';
    $ref->{word} = '';
    $ref->{len}  = '';
    $ref->{word_len} ='';

    $ref;
};

sub edit {
    my ($ref) = @_;
    while ($ref->{win}->window and !$ref->{OK}) {
        WaitNextEvent;

        if ($ref->{hte}->selStart == $ref->{hte}->selEnd) { 
            DisableItem($ref->{newEdit}, 1);
            DisableItem($ref->{newEdit}, 2)
        }
        else {
            EnableItem($ref->{newEdit}, 1);
            EnableItem($ref->{newEdit}, 2)
        }

        if (TEGetScrapLength() == 0) { DisableItem($ref->{newEdit}, 3) }
        else { EnableItem($ref->{newEdit}, 3) }

        if ($ref->{saved}) { DisableItem($ref->{newFile}, 4) }
        else { EnableItem($ref->{newFile}, 4) }

        if ($ref->{file}) { DisableItem($ref->{newFile}, 1) }
        else { EnableItem($ref->{newFile}, 1) }

        if(defined FrontWindow() and ${FrontWindow()} == ${$ref->{ptr}}) { 
            $ref->change_menu_bar() 
        }
    }
    $ref->DESTROY;
    if ( $ref->{hte}->teLength > 0) { return TEGetText($ref->{hte})->get }
    else { return undef }
}

sub adjust_controls {
    my ($ref) = @_;
    my $port = $ref->{win}->window->portRect;
    my $doc_v = ($ref->{hte}->nLines)*($ref->{hte}->lineHeight);
    my ($h_hilite, $v_hilite);

    SetControlMaximum($ref->{ch}, ($ref->{lw}) - ($port->right) + 21);
    if (($ref->{lw})-($port->right)+21 <= 0) { $h_hilite = -1 } else { $h_hilite = 0 }
    HiliteControl($ref->{ch}, $h_hilite);

    SetControlMaximum($ref->{cv}, $doc_v-($port->bottom)+21);
    if ($doc_v-($port->bottom)+21 <= 0) { $v_hilite = -1 } else { $v_hilite = 0 }
    HiliteControl($ref->{cv}, $v_hilite);
}

sub revise_layout {
    my ($ref) = @_;
    my $port = $ref->{ptr}->portRect;
    my ($h_hilite, $v_hilite);
    my $doc_v = ($ref->{hte}->nLines)*($ref->{hte}->lineHeight);

    if ($ref->{h_offset} <= $port->right - 21 - $ref->{lw}) { 
        $ref->{h_offset} = $port->right - 21 - $ref->{lw};
    }
    if ($ref->{h_offset} > 0) { $ref->{h_offset} = 0 }

    if ($ref->{v_offset} <= $port->bottom - 21 - $doc_v) {
        $ref->{v_offset} =  $port->bottom - 21 - $doc_v 
    }
    if ($ref->{v_offset} > 0) { $ref->{v_offset} = 0 }

    $ref->{view} = Rect->new(0, 0, $port->right-15, $port->bottom-15);
    my $str = TEGetText($ref->{hte})->get;
    TEDispose $ref->{hte};
    my $r = OffsetRect($ref->{dest}, $ref->{h_offset}, $ref->{v_offset});
    $ref->{hte} = TENew($r, $ref->{view});
    TESetText($str, $ref->{hte});

# adjust vertical position of horizontal bar
    MoveControl($ref->{ch}, -1, $port->bottom-15);
    SizeControl($ref->{ch}, $port->right-13, 16);

# adjust horizontal position of vertical bar
    MoveControl($ref->{cv}, $port->right-15, -1);
    SizeControl($ref->{cv}, 16, $port->bottom-13);

    $ref->adjust_controls();
    EraseRect(Rect->new(0, 0, $port->right, 5));
    $ref->{win}->redraw; 
}

sub get_key {
    my ($ref, $win, $key) = @_;
    my $hte = $ref->{hte};
    if ($CurrentEvent->modifiers & 256) {
        if    ($key ==  97) { TESetSelect(0, $hte->teLength, $hte) }
        elsif ($key == 102) { $ref->get_string() }
        elsif ($key == 103) { $ref->search_again() }
        elsif ($key == 111) { $ref->open_file() }
        elsif ($key == 115) { $ref->save_file() }
        elsif ($key == 119) { $ref->close_file() }
        elsif ($key ==  99) { TECopy($hte) }
        elsif ($key == 118) { TEPaste($hte); $ref->{saved} = 0}
        elsif ($key == 120) { TECut($hte) }
        elsif ($key == 113) { $ref->{OK} = 1 }
        elsif ($key == 46)  { $ref->{OK} = 1 }
    }
    else {
        TEKey(chr($key), $hte);
        $ref->{saved} = 0;
        my $ls = $hte->lineHeight;

        if ($hte->selRect->right > $ref->{win}->window->portRect->right-16) {
            my $max = GetControlMaximum($ref->{ch});
            TEScroll(-($max + $ref->{h_offset}), 0, $hte);
            $ref->{h_offset} = -$max
        }
        elsif ($hte->selRect->right < 6) {
            TEScroll(-$ref->{h_offset}, 0, $hte);
            $ref->{h_offset} = 0
        }
        SetControlValue($ref->{ch}, -$ref->{h_offset});

        if ($hte->selRect->top < 0) {
            TEScroll(0, $ls, $hte);
            $ref->{v_offset} += $ls
        }
        if ($hte->selRect->top > $ref->{win}->window->portRect->bottom -16 -$ls) {
            TEScroll(0, -$ls, $hte);
            $ref->{v_offset} -= $ls
        }
        SetControlValue($ref->{cv}, -$ref->{v_offset});
    }
    $ref->adjust_controls();
}

sub do_draw {
    my($ref, $win) = @_;
    my $port = $ref->{win}->window->portRect;
    DrawControls($ref->{win}->window);
    TEActivate($ref->{hte});
    TEGetText($ref->{hte});
    $ref->{view} = Rect->new(0, 0, $port->right-16, $port->bottom-16);
    TEUpdate($ref->{view}, $ref->{hte});
}

sub get_click {
    my($ref, $win, $pt) = @_;
    my $extend = ($CurrentEvent->modifiers & shiftKey) != 0;
    TEClick($pt, $extend, $ref->{hte});
}

sub vertical_scroll {
    my ($ref, $cv, $w, $part) = @_;
    my $ls = $ref->{hte}->lineHeight;

    if (TestControl($ref->{cv}, $part) ==129) {
        TrackControl($ref->{cv}, $part, 0);
        my $scroll = $ref->{v_offset} + GetControlValue($ref->{cv});
        TEScroll(0, -$scroll, $ref->{hte});
        $ref->{v_offset} = -GetControlValue($ref->{cv});
    }
    elsif(TestControl($ref->{cv}, $part) == 20) {
        TrackControl($ref->{cv}, $part, sub { $ref->scroll_up(@_) } )
    }
    elsif(TestControl($ref->{cv}, $part) == 21) {
        TrackControl($ref->{cv}, $part, sub { $ref->scroll_down(@_) } )
    }
    elsif(TestControl($ref->{cv}, $part) == 22) {
        TrackControl($ref->{cv}, $part, sub { $ref->page_up(@_) })
    }
    elsif(TestControl($ref->{cv}, $part) == 23) {
        TrackControl($ref->{cv}, $part, sub { $ref->page_down(@_) })
    }
}

sub scroll_up {
    my ($ref, $ctrl, $part) = @_;
    my $ls = $ref->{hte}->lineHeight;

    if ($part == 20) {
        if ($ref->{v_offset} < -$ls) {
            TEScroll(0, $ls, $ref->{hte});
            $ref->{v_offset} += $ls;
        }
        elsif ($ref->{v_offset} < 0) {
            TEScroll(0, -$ref->{v_offset}, $ref->{hte});
            $ref->{v_offset} = 0;
        }
        SetControlValue($ctrl, -$ref->{v_offset});
    }
}

sub page_up {
    my ($ref, $ctrl, $part) = @_;
    my $ls = $ref->{hte}->lineHeight;
    my $ph = $ref->{win}->window->portRect->bottom - (16 + $ls);
    if ($part == 22) {
        if ($ph <= -$ref->{v_offset}) {
            TEScroll(0, $ph, $ref->{hte});
            $ref->{v_offset} += $ph;
        }
        else {
            TEScroll(0, -$ref->{v_offset}, $ref->{hte});
            $ref->{v_offset} = 0;
        }
        SetControlValue($ctrl, -$ref->{v_offset});
    }
}

sub scroll_down {
    my ($ref, $ctrl, $part) = @_;
    my $ls = $ref->{hte}->lineHeight;
    my $max = GetControlMaximum($ctrl);

    if ($part == 21) {
        if ($ref->{v_offset} > -($max-$ls)) {
            TEScroll(0, -$ls, $ref->{hte});
            $ref->{v_offset} -= $ls;
        }
        elsif ($ref->{v_offset} > -$max) {
            TEScroll(0, -($max+$ref->{v_offset}), $ref->{hte});
            $ref->{v_offset} = -$max
        }
        SetControlValue($ctrl, -$ref->{v_offset});
    }
}

sub page_down {
    my ($ref, $ctrl, $part) = @_;
    my $ls = $ref->{hte}->lineHeight;
    my $max = GetControlMaximum($ctrl);
    my $ph = $ref->{win}->window->portRect->bottom - (16 + $ls);

    if ($part == 23) {
        if ($ref->{v_offset} > -($max - $ph)) {
            TEScroll(0, -$ph, $ref->{hte});
            $ref->{v_offset} -= $ph
        }
        else {
            TEScroll(0, -($max + $ref->{v_offset}), $ref->{hte});
            $ref->{v_offset} = -$max
        }
        SetControlValue($ctrl, -$ref->{v_offset});
    }
}

sub horizontal_scroll {
    my ($ref, $ch, $w, $part) = @_;

    if (TestControl($ref->{ch}, $part) == 129) {
        TrackControl($ref->{ch}, $part, 0);
        my $scroll = $ref->{h_offset} + GetControlValue($ref->{ch});
        TEScroll(-$scroll, 0, $ref->{hte});
        $ref->{h_offset} = -GetControlValue($ref->{ch});
    }
    elsif(TestControl($ref->{ch}, $part) == 20) {
        TrackControl($ref->{ch}, $part, sub { $ref->scroll_left(@_) } )
    }
    elsif(TestControl($ref->{ch}, $part) == 21) {
        TrackControl($ref->{ch}, $part, sub { $ref->scroll_right(@_) } )
    }
    elsif(TestControl($ref->{ch}, $part) == 22) {
        TrackControl($ref->{ch}, $part, sub { $ref->page_left(@_) } )
    }
    elsif(TestControl($ref->{ch}, $part) == 23) {
        TrackControl($ref->{ch}, $part, sub { $ref->page_right(@_) } )
    }
}

sub scroll_left {
    my ($ref, $ctrl, $part) = @_;
    if ($part == 20) {
        if ($ref->{h_offset} < -10) {
            TEScroll(10, 0, $ref->{hte});
            $ref->{h_offset} += 10;
        }
        elsif ($ref->{h_offset} < 0) {
            TEScroll(-$ref->{h_offset}, 0, $ref->{hte});
            $ref->{h_offset} = 0;
        }
    }
    SetControlValue($ctrl, -$ref->{h_offset});
}

sub scroll_right {
    my ($ref, $ctrl, $part) = @_;
    my $max = GetControlMaximum($ctrl);
    if ($part == 21) {
        if ($ref->{h_offset} > -($max-10)) {
            TEScroll(-10, 0, $ref->{hte});
            $ref->{h_offset} -= 10;
        }
        elsif ($ref->{h_offset} > -$max) {
            TEScroll(-($max+$ref->{h_offset}), 0, $ref->{hte});
            $ref->{h_offset} = -$max
        }
    }
    SetControlValue($ctrl, -$ref->{h_offset});
}

sub page_left {
    my ($ref, $ctrl, $part) = @_;
    if ($part == 22) {
        TEScroll(-$ref->{h_offset}, 0, $ref->{hte});
        $ref->{h_offset} = 0
    }
    SetControlValue($ctrl, -$ref->{h_offset});
}

sub page_right {
    my ($ref, $ctrl, $part) = @_;
    my $max = GetControlMaximum($ctrl);
    if ($part == 23) {
        TEScroll(-($max + $ref->{h_offset}), 0, $ref->{hte});
        $ref->{h_offset} = -$max
    }
    SetControlValue($ctrl, -$ref->{h_offset});
}

sub new_menu {
    my ($ref) = @_;
    $ref->{2048} = MacMenu->new (
        2048, 'MPEdit', (
            ['Cut',        sub { $ref->edit_menu(@_) }, 'X'],
            ['Copy',       sub { $ref->edit_menu(@_) }, 'C'],
            ['Paste',      sub { $ref->edit_menu(@_) }, 'V'],
            [],
            ['Select All', sub { $ref->edit_menu(@_) }, 'A'],
            [],
            ['Find',       sub { $ref->edit_menu(@_) }, 'F'],
            ['Find Again', sub { $ref->edit_menu(@_) }, 'G'],
        )
    );
   $ref->{2049} = MacMenu->new (
        2049, 'MPFile', (
            ['Open',       sub { $ref->file_menu(@_) }, 'O'],
            [],
            ['Close',      sub { $ref->file_menu(@_) }, 'W'],
            ['Save',       sub { $ref->file_menu(@_) }, 'S'],
            ['Save AsÉ',   sub { $ref->file_menu(@_) }, '' ],
            [],
            ['Quit',       sub { $ref->file_menu(@_) }, 'Q'],
        )
    );
}

sub file_menu {
    my ($ref, $menu, $item) = @_;
    if ($menu == 2049) {
        if    ($item == 1) { $ref->open_file(); }
        elsif ($item == 3) { $ref->close_file() }
        elsif ($item == 4) { $ref->save_file() }
        elsif ($item == 5) { $ref->save_as() }
        elsif ($item == 7) { $ref->{OK} = 1 }
    }
}

sub edit_menu {
    my ($ref, $menu, $item) = @_;
    $ref->{saved} = 0;
    if ($menu == 2048) { 
        if    ($item == 1) { TECut($ref->{hte}) }
        elsif ($item == 2) { TECopy($ref->{hte}) }
        elsif ($item == 3) { TEPaste($ref->{hte}); }
        elsif ($item == 5) { TESetSelect(0, $ref->{hte}->teLength, $ref->{hte}) }
        elsif ($item == 7) { $ref->get_string() }
        elsif ($item == 8) { $ref->search_again() }
    }
    return 1
}

sub import_string {
    my ($ref, $txt) = @_;
    $ref->{file} = 'Import' if $txt;
    SetWTitle $ref->{win}->window, 'IMPORT';
    TESetText($txt, $ref->{hte});
    TESetSelect(0, 0, $ref->{hte});
    $ref->adjust_controls();
    $ref->{win}->redraw;
    $ref->{saved} = 1;
}


sub open_file {
    my ($ref, $ext) = @_;
    if ($ref->{file}) { print chr(7); return }
    elsif ($ext) { $ref->{file} = $ext }
    else {
        $ref->{file} = MacPerl::Choose(4, 0, '');
        return unless $ref->{file};
    }
    undef $/;
    open(IN, $ref->{file}) or die "$!\n";
    my $str = <IN>;
    close IN;
    $/ = "\n";
    $ref->{file} =~ /(.*):(.*)/;
    SetWTitle $ref->{win}->window, $2;
    TESetText($str, $ref->{hte});
    TESetSelect(0, 0, $ref->{hte});
    $ref->adjust_controls();
    $ref->{win}->redraw;
    $ref->{saved} = 1;
}

sub close_file {
    my ($ref) = @_;
    my $str = $ref->{file} ? $ref->{file} : "Untitled window";
    if ($ref->{saved}) { $ref->{OK} = 1 }
    else {
        my $a = MacPerl::Answer(
            "$str\n Save to disk before closing?\n",
            'Save', 'Cancel', "Don't Save"
        );
        if    ($a == 0) { $ref->{OK} = 1; $ref->{file} = '' }
        elsif ($a == 1) { return 0 }
        elsif ($a == 2) {
            if (defined $ref->{file}) { $ref->save_file() }
            else { $ref->save_as() }
            $ref->{OK} = 1;
        }
    }
}

sub save_file {
    my ($ref) = @_;
    if ($ref->{saved}) { print chr(7); return }
    open(OUT, ">$ref->{file}") or die "$!\n";
    print OUT TEGetText($ref->{hte})->get;
    close OUT;
    MacPerl::SetFileInfo('R*ch', 'TEXT', $ref->{file});
    $ref->{saved} = 1;
    $ref->{file} = '';
}

sub save_as {
    my ($ref) = @_;
    my $prompt = $ref->{file} ? $ref->{file} : 'MPDefault';
    my $f = MacPerl::Choose(4, 0, 'Save window as:', '', 3, $prompt);
    if (defined $f) { $ref->{file} = $f }
    else { return 1 }
    open(OUT, ">$ref->{file}") or die "$!\n";
    print OUT TEGetText($ref->{hte})->get;
    close OUT;
    MacPerl::SetFileInfo('R*ch', 'TEXT', $ref->{file});
    $ref->{file} =~ /(.*):(.*)/;
    SetWTitle $ref->{win}->window, $2;
    $ref->{saved} = 1;
    $ref->{file} = ''
}

sub get_string {
    my ($ref) = @_;
    $ref->{word} = MacPerl::Ask('Search for...', '');
    $ref->{win}->redraw;
    $ref->first_find()
}

sub first_find {
    my ($ref) = @_;
    $ref->{doc} = TEGetText($ref->{hte})->get;
    $ref->{len} = 0;
    $ref->{word_len} = 0;
    $ref->search_again()
}

sub show_word {
    my ($ref) = @_;
    my $v_pt = TEGetPoint($ref->{len}, $ref->{hte})->v;
    my $r_pt = TEGetPoint($ref->{len} + $ref->{word_len}, $ref->{hte})->h;
    my $l_pt = TEGetPoint($ref->{len}, $ref->{hte})->h;

    TESetSelect($ref->{len}, ($ref->{len}+$ref->{word_len}), $ref->{hte});
    my $v_max = $ref->{win}->window->portRect->bottom -16;
    my $r_max = $ref->{win}->window->portRect->right - 16;

    if ($v_pt > $v_max) {
        TEScroll(0, -$v_pt + $v_max, $ref->{hte});
        $ref->{v_offset} -= $v_pt - $v_max;
        SetControlValue($ref->{cv}, -$ref->{v_offset})
    }
    if ($r_pt > $r_max) {
        TEScroll(-$r_pt + $r_max, 0, $ref->{hte});
        $ref->{h_offset} -= $r_pt - $r_max;
        SetControlValue($ref->{ch}, -$ref->{h_offset})
    }

    if ($l_pt < 0 ) {
        TEScroll(-$l_pt, 0, $ref->{hte});
        $ref->{h_offset} -= $l_pt;
        SetControlValue($ref->{ch}, -$ref->{h_offset})
    }
}

sub search_again {
    my ($ref) = @_;
    while($ref->{doc} =~ /\b($ref->{word})\b/) {
        $ref->{len} += length($`);
        $ref->{word_len} = length($1);
        $ref->show_word();
        $ref->{len} += $ref->{word_len};
        $ref->{doc} = $';
        return
    }
    print chr(7), chr(7);
    return
}

sub change_menu_bar {
    my($ref) = @_;
    DeleteMenu(130);
    DeleteMenu(129);
    InsertMenu $ref->{newEdit}, 133;
    InsertMenu $ref->{newFile}, 2048;
    DrawMenuBar()
}

sub restore_menu_bar {
    my ($ref) = @_;
    DeleteMenu(2048);
    DeleteMenu(2049);
    InsertMenu $ref->{oldEdit}, 133;
    InsertMenu $ref->{oldFile}, 130;
    DrawMenuBar()
}

sub mousePress {
    my ($ref, $ev) = @_;
    my $pt = $ev->where;

    my ($code, $window) = FindWindow($pt);
    if (defined $window and $$window == ${$ref->{ptr}}) { 
        SelectWindow($window);
        $ref->change_menu_bar();
        if ($code == 3) { $ref->{win}->click(GlobalToLocal($pt)) }
        if ($code == 4) { $ref->{win}->drag($pt) }
        if ($code == 5) { $ref->{win}->grow($pt) }
        if ($code == 6) { TrackGoAway($window, $pt); $ref->close_file() }
        if ($code == 7) { $ref->{win}->zoom($pt, 7) }
        if ($code == 8) { $ref->{win}->zoom($pt, 8) }
        return 1
    }
    else { 
        $ref->restore_menu_bar() unless $code == 1;
        return 0
    }
}

sub DESTROY {
    my ($ref) = @_;
    $ref->restore_menu_bar();
    DisposeMenu($ref->{newEdit}) if defined $ref->{newEdit};
    DisposeMenu($ref->{newFile}) if defined $ref->{newFile};
    DisposeControl($ref->{cv}) if defined $ref->{cv};
    DisposeControl($ref->{ch}) if defined $ref->{ch};
    $ref->{win}->dispose if defined $ref->{win};
}

1;